;; This file is part of eris-cl.
;; Copyright (C) 2022 Piotr Szarmański

;; eris-cl is free software: you can redistribute it and/or modify it under the
;; terms of the GNU Lesser General Public License as published by the Free
;; Software Foundation, either version 3 of the License, or (at your option) any
;; later version.

;; eris-cl is distributed in the hope that it will be useful, but WITHOUT ANY
;; WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
;; A PARTICULAR PURPOSE. See the GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License along with
;; eris-cl. If not, see <https://www.gnu.org/licenses/>.

(in-package :eris)

(defclass file-backend (encoding-backend decoding-backend)
  ((directory :initarg :directory :type (or string pathname)
              :documentation
              "Directory containing ERIS data.")))


(define-condition file-backend-error (error)
  ())

(define-condition directory-error (file-backend-error)
  ((message :type string :initarg :message))
  (:report (lambda (condition stream)
             (format stream "~a" (slot-value condition 'message)))))

(defmethod shared-initialize :after ((file-backend file-backend) slot-names
                                     &rest initargs
                                     &key (directory nil directory-p)
                                     &allow-other-keys)
  
  (declare (ignore initargs slot-names))
  (when (or (null directory-p) (null (pathname-directory directory)))
    (error 'directory-error :message "Incorrectly specified directory."))
  (with-slots (directory output-function fetch-function) file-backend
    (when (or (pathname-name directory)))
    (setf fetch-function
          (lambda (reference)
            (let* ((base32 (bytes-to-base32-unpadded reference))
                   (file (merge-pathnames directory base32)))
              (if (probe-file file)
                  (alexandria:read-file-into-byte-vector file)
                  (error 'missing-block :reference reference))))
          output-function
          (lambda (block reference)
            (let* ((base32 (bytes-to-base32-unpadded reference))
                   (file (merge-pathnames directory base32)))
              (unless (probe-file file)
                (alexandria:write-byte-vector-into-file block file)))
            block))))

(defmethod fetch-data (read-capability (backend file-backend) &key &allow-other-keys)
  (declare (type read-capability read-capability))
  (with-slots (fetch-function) backend
    (eris-decode read-capability fetch-function)))

(defmethod store-data (input (backend file-backend) &key (secret null-secret) &allow-other-keys)
  (declare (type octet-vector secret))
  (with-slots (output-function) backend
    (eris-encode input
                 (if (> (etypecase input
                          (stream (file-length input))
                          (vector (length input)))
                        (* 2 16384))
                     32kib
                     1kib)
                 output-function
                 :hash-output nil
                 :secret secret)))